CMakeLists.txt

# CMake for GammaWare/CORE
# O. Stezowski
#
# To add a file, add it in the with_dictionnary list or in the without_dictionnary list depending
#  whether or not the ROOT dictionnary is to be generated.
#  !! Do not forget to fill the LinkDef file !!
#  !! Do not forget to add EXTRA_INTERNAL_LIBRARIES and EXTRA_EXTERNAL_LIBRARIES with the names of the libraries this one relies on !!
#
project (core)
#
MESSAGE("[GW]  + root/${PROJECT_NAME}")
#
#
set(GWLIBNAME GWCORE)
#
# headers / dictionnary / sources
#
# so far no automatic methods for computing which class has a dictionnary or not
# manual method : base file name separated in two lists with different treatment.
#
if ( EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/GwConfig.h ) # in case build with configure has been called previously
    file(REMOVE ${CMAKE_CURRENT_SOURCE_DIR}/GwConfig.h)
endif()
#
set( with_dictionnaries
    BaseNucleus
    Data
    Env
    GammaTracker
    InfoData
    Measure
    PadManager
    RandObj
    Random
)
set( without_dictionnaries
    SingletonDestroyer
    GwCentralLog
    GwLogCollector
    GwLogMessage
    BashColor
#	../../adf/CentralLog  # to avoid having the same file in two directories in the svn
#	../../adf/LogCollector
#	../../adf/LogMessage
    XtermProgressBar
)
# add includes : root + current (before to have the latest) + all gw includes copied in CMAKE_BINARY_DIR/include
#
include_directories(${ROOT_INCLUDES})
include_directories(${CMAKE_BINARY_DIR}/include)
include_directories(BEFORE ${CMAKE_CURRENT_SOURCE_DIR})
#
set (ALL_GW_INCLUDES ${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_BINARY_DIR}/include ${ROOT_INCLUDES})
#
link_directories(${ROOT_LIBRARY_DIR})
link_directories(${CMAKE_LIBRARY_OUTPUT_DIRECTORY})
#
# configure file
#
configure_file (
    "${CMAKE_CURRENT_SOURCE_DIR}/GwConfig.h.cmake"
    "${CMAKE_BINARY_DIR}/include/GwConfig.h"
)
#
# headers / linkdef etc ...
#
set(headers ${CMAKE_BINARY_DIR}/include/GwConfig.h)
set(all_headers "")
set(sources "")
#
# set headers/ etc and generate dictionnary for the files which require it
#
foreach( f ${with_dictionnaries} )
    set(sources ${sources} ${CMAKE_CURRENT_SOURCE_DIR}/${f}.cpp)
    set(headers ${headers} ${CMAKE_CURRENT_SOURCE_DIR}/${f}.h)
endforeach()
#
# Dictionnary from one file only 'a la ROOT' + internal and external dependencies
#
ROOT_GENERATE_DICTIONARY(G__${GWLIBNAME} ${headers} MODULE ${GWLIBNAME} LINKDEF ${CMAKE_CURRENT_SOURCE_DIR}/LinkDef.h OPTIONS "")
set( EXTRA_EXTERNAL_LIBRARIES Core Graf MathCore XMLParser Hist Gui)
#
foreach( f ${without_dictionnaries} )
    set(sources ${sources} ${CMAKE_CURRENT_SOURCE_DIR}/${f}.cpp)
    set(headers ${headers} ${CMAKE_CURRENT_SOURCE_DIR}/${f}.h)
endforeach()
#

#----------------------------------------------------------------------------
#
# Use root functions to generate the library and the root map file
#
if ( with_dictionnaries )
    ROOT_LINKER_LIBRARY(${GWLIBNAME} ${sources} G__${GWLIBNAME}.cxx DEPENDENCIES ${EXTRA_EXTERNAL_LIBRARIES})
    ROOT_GENERATE_ROOTMAP(${GWLIBNAME} LINKDEF ${CMAKE_CURRENT_SOURCE_DIR}/LinkDef.h DEPENDENCIES ${EXTRA_EXTERNAL_LIBRARIES})
else ()
    ROOT_LINKER_LIBRARY(${GWLIBNAME} ${sources} DEPENDENCIES ${EXTRA_EXTERNAL_LIBRARIES})
endif()
#
# copy headers file in a single directory	so that is becomes available for ohers sub-projects
#
# because cmake2.6 does not provide COPY in file, do it another way
if( ${CMAKE_VERSION} VERSION_GREATER "2.8.0" )
    file(COPY ${headers} DESTINATION ${CMAKE_BINARY_DIR}/include)
else()
    if ( EXISTS ${CMAKE_BINARY_DIR}/include )
    else()
        execute_process(COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/include/ )
    endif()
    foreach ( f ${headers} )
        execute_process(COMMAND ${CMAKE_COMMAND} -E copy ${f} ${CMAKE_BINARY_DIR}/include/ )
    endforeach()
endif()
#
# Install lib and headers
#
install(TARGETS ${GWLIBNAME}
    RUNTIME DESTINATION bin
    LIBRARY DESTINATION lib
    ARCHIVE DESTINATION lib
    COMPONENT libraries)
#
# special treatments, 
#
install(FILES ${headers} DESTINATION ${GW_INCLUDE_DIR} COMPONENT headers )
if ( with_dictionnaries )
    install(FILES ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/lib${GWLIBNAME}_rdict.pcm DESTINATION lib COMPONENT libraries )
    install(FILES ${CMAKE_LIBRARY_OUTPUT_DIRECTORY}/lib${GWLIBNAME}.rootmap DESTINATION lib COMPONENT libraries )
endif()