convergence_detection.ml

open Core
open Bistro.EDSL
open Bistro.Std
open File_formats
open Bistro_bioinfo.Std
open Defs

type result = [
  | `Pcoc of [`pcoc] directory workflow
  | `Pcoc_gamma of [`pcoc] directory workflow
  | `Diffsel of [`diffsel] directory workflow
  | `Diffsel_bis of [`diffsel] directory workflow
  | `Identical_LG of [`identical] directory workflow
  | `Identical_WAG of [`identical] directory workflow
]

let meth_string_of_result = function
  | `Pcoc _ -> "pcoc"
  | `Pcoc_gamma _ -> "pcoc_gamma"
  | `Diffsel _ -> "diffsel"
  | `Diffsel_bis _ -> "diffsel_bis"
  | `Identical_LG _ -> "identical_LG"
  | `Identical_WAG _ -> "identical_WAG"

type dataset_res = {
  model_prefix : string ;
  tree_prefix : string ;
  res_by_tools: result list ;
  merged_results : text_file workflow ;
  plot_merged_results : svg workflow ;
}

let merge_results ~res_by_tools : text_file workflow =
  let env = docker_image ~account:"carinerey" ~name:"ete3" ~tag:"3.0.0b35" () in
  let command = List.map res_by_tools ~f:(fun res ->
      let w = match res with
        | `Pcoc d -> Pcoc.results d
        | `Pcoc_gamma d -> Pcoc.results d
        | `Diffsel d -> Diffsel.selector d
        | `Diffsel_bis d -> Diffsel.selector d
        | `Identical_LG d -> Identical.results d
        | `Identical_WAG d -> Identical.results d
      in
      let opt = match res with
        | `Pcoc _ -> string "--pcoc"
        | `Pcoc_gamma _ -> string "--pcoc_gamma"
        | `Diffsel _ -> string "--diffsel"
        | `Diffsel_bis _ -> string "--diffsel_bis"
        | `Identical_LG _ -> string "--identical_LG"
        | `Identical_WAG _ -> string "--identical_WAG"
      in
      seq ~sep:" " [opt; dep w]
    )
  in
  workflow ~descr:"convergence_detection.merge_results" [
    cmd "python" ~env [
            file_dump (string Scripts.merge_det_results) ;
            opt "-o" ident dest ;
            seq ~sep:" " command ;
          ] ;
  ]


let plot_merge_results ~(res_by_tools:result list) ~tree ~faa ~tsv : svg workflow =
  let plot_all_sites = true in
  (*let env = docker_image ~account:"carinerey" ~name:"ete3" ~tag:"3.0.0b35" () in*)
  let env = docker_image ~account:"carinerey" ~name:"pcoc" ~tag:"06212018" () in
  (* use of pcoc env due to its working X server for dra plot with ete3 *)
  let meths = List.map res_by_tools ~f:(fun res ->
    let opt = match res with
      | `Pcoc _ -> "PCOC"
      | `Pcoc_gamma _ -> "PCOC_gamma"
      | `Diffsel _ -> "Diffsel"
      | `Diffsel_bis _ -> "Diffsel_bis"
      | `Identical_LG _ -> "Identical_LG08"
      | `Identical_WAG _ -> "Identical_WAG01"
    in
    string opt
  ) |> seq ~sep:","
  in
  let meths_t = List.map res_by_tools ~f:(fun res ->
    let opt = match res with
      | `Pcoc _ -> "PCOC:0.99"
      | `Pcoc_gamma _ -> "PCOC_gamma:0.99"
      | `Diffsel _ -> "Diffsel:0.9"
      | `Diffsel_bis _ -> "Diffsel_bis:0.9"
      | `Identical_LG _ -> "Identical_LG08:0.9"
      | `Identical_WAG _ -> "Identical_WAG01:0.9"
    in
    string opt
  ) |> seq ~sep:","
  in
  let package_diffsel_script_utils = tmp // "diffsel_script_utils.py" in
  let package_plot_data = tmp // "plot_data.py" in
  let script_plot_convergent_sites = tmp // "plot_convergent_sites.py" in
  let out = dest // "results.svg" in
  workflow ~descr:"convergence_detection.plot_results" [
    docker env (
      and_list [
        mkdir_p tmp ;
        mkdir_p dest ;
        cd tmp ;

        cmd "cp" [ file_dump (string Scripts.diffsel_script_utils) ; package_diffsel_script_utils ] ;
        cmd "cp" [ file_dump (string Scripts.plot_data) ; package_plot_data] ;
        cmd "cp" [ file_dump (string Scripts.plot_convergent_sites); script_plot_convergent_sites ] ;

        cmd "python" [
          string "plot_convergent_sites.py" ;
          opt "-msa" dep faa ;
          opt "-tsv" dep tsv ;
          opt "-tree" dep tree ;
          opt "-out" ident out ;
          opt "-meth" ident meths ;
          opt "-t" ident meths_t ;
          flag string "--all_sites" plot_all_sites ;
        ]
      ]
    )
  ]