inside_4.f90

module inside_4_m

  implicit none

contains

  logical function inside_4(distance, center, v)

    ! This procedure returns true if the four points center \pm
    ! (distance(1), 0) and center \pm (0, distance(2)) are inside
    ! the polygon v.

    use geometry, only: polygon_contains_point

    real, intent(in):: distance(:) ! (2)
    real, intent(in):: center(:) ! (2) coordinates of the center point

    real, intent(in):: v(:, :) ! (2, :) vertices of the polygon
    ! The last vertex should repeat the first vertex.

    !-------------------------------------------------------------

    ! On the eastern way:
    inside_4 = polygon_contains_point(v, [center(1) + distance(1), center(2)])

    if (inside_4) then
       ! On the northern way:
       inside_4 = polygon_contains_point(v, &
            [center(1), center(2) + distance(2)])

       if (inside_4) then
          ! On the western way:
          inside_4 = polygon_contains_point(v, &
               [center(1) - distance(1), center(2)])

          if (inside_4) then
             ! On the southern way:
             inside_4 = polygon_contains_point(v, &
                  [center(1), center(2) - distance(2)])
          end if
       end if
    end if

  end function inside_4

end module inside_4_m